2楼: Originally posted by tracel at 2012-12-09 20:59:38
看起来貌似很容易写，shell+awk 就可以，不过把你命令的结果组合下就可以了。

不过实在没看懂你需求是什么。你既然懂得脚本，不妨具体解决不了的问题贴出来，更方便一点。

4楼: Originally posted by chembetsey at 2012-12-09 23:26:27
100金币太少了，给我500金币，我给你写。

6楼: Originally posted by wuy069 at 2012-12-10 08:08:41
没问题，你只要写好了，满足我上面说的要求就行...

7楼: Originally posted by chembetsey at 2012-12-10 12:46:24
我写出来了，你要是感兴趣我发给你。...

7楼: Originally posted by chembetsey at 2012-12-10 12:46:24
我写出来了，你要是感兴趣我发给你。...

9楼: Originally posted by tracel at 2012-12-10 16:51:07
贴出来，大家学习下写法嘛...

[font=Courier New]
qhost -j | \
awk ' BEGIN {
        print "------------------------------------------------------------------------------------------------"
        print " Node                    Load    Ncpu   Mem   MemUse     Swap  SwapUse    State  Task  Job/User"
        print "------------------------------------------------------------------------------------------------"
        Njob=0
        Ntsk=0
        }

/lx26-amd64/ {
        if(Ntsk>0) {
                if(Ntsk>=Ncpu) printf("%8s %4d   ", "Busy", Ntsk)
                else printf("%8s %4d   ", "Free", Ntsk)
        }
        for(i=1; i<=Njob; i++) {
                printf(" %s/%s", Ijob[i], Ujob[i])
        }
        if(Njob>0) print ""
        Njob=0
        Ntsk=0
        Ncpu=$3
        printf("%-20s %8s %4s %8s %8s %8s %8s", $1, $4, $3, $5, $6, $7, $8)
}
/@.+/ {
        if(NF>4) {
                Njob=Njob+1
                Ijob[Njob]=$1
                Ujob[Njob]=$4
        }
        Ntsk=Ntsk+1
}

END { if(Ntsk>0) {
                if(Ntsk>=Ncpu) printf("%8s %4d   ", "Busy", Ntsk)
                else printf("%8s %4d   ", "Free", Ntsk)
         }
        for(i=1; i<=Njob; i++) printf(" %s/%s", Ijob[i], Ujob[i])
        print ""
        print "------------------------------------------------------------------------------------------------"
}
'
输出
------------------------------------------------------------------------------------------------
Node                    Load    Ncpu   Mem   MemUse     Swap  SwapUse    State  Task  Job/User
------------------------------------------------------------------------------------------------
cluster                  2.99    4     3.9G     1.2G     4.0G      0.0    Free    3    29/wuy 30/wuy
------------------------------------------------------------------------------------------------
[/font]

[font=Courier New]
qstat -u '*' | \
awk ' BEGIN { getline; getline
                print "---------------------------------------------------------------------------------------------------------------"
                print " Job-ID   Name        User  State     Start Time           Queue               Slots     ReqTime     ElapTime"
                print "---------------------------------------------------------------------------------------------------------------"
        }

        {        if(NF==9) printf("%4d %12s %8s %4s %20s %25s %4d", $1, $3, $4, $5, $6" "$7, $8, $9)
                else printf("%4d %12s %8s %4s %20s %25s %4d", $1, $3, $4, $5, $6" "$7, " ", $8)
                "qstat -j " $1 " | grep h_rt" | getline Treq
                sub(/hard resource_list:.+h_rt=/, "", Treq)
                printf(" %12s", dTime(Treq))
                "date --date=\""$6" "$7"\" +%s" | getline Nsec
                printf(" %12s\n", dTime(systime()-Nsec))
        }
END {                 print "---------------------------------------------------------------------------------------------------------------"}
function dTime(Nsec) {
        return int(Nsec/86400)":"int((Nsec%86400)/3600)":"int((Nsec%3600)/60)":"Nsec%60
}
'
输出
---------------------------------------------------------------------------------------------------------------
Job-ID   Name        User  State     Start Time           Queue               Slots     ReqTime     ElapTime
---------------------------------------------------------------------------------------------------------------
  29   gmstest1.s      wuy    r  12/10/2012 15:11:37       all.q@cluster.local    1     50:0:0:0   0:14:38:47
  30   gmstest2.s      wuy    r  12/10/2012 15:12:07       all.q@cluster.local    2     50:0:0:0   0:14:38:18
  31     core3.sh      wuy   qw  12/10/2012 15:12:27                              3      0:1:0:0   0:14:37:58
---------------------------------------------------------------------------------------------------------------
[/font]