[交流] 如何在已有命令流文件中，增加结构自重的影响 已有1人参与

!*  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,DENS,1,,2400

! Input file for ANSYS
! ANSYS Parametric Design Language (APDL)
! Simulation of Wedge Splitting Test with user-defined material
! Rotating smeared crack model
! Usermat.F

FINI    ! exit processor, if necessary
/Clear  ! crear database
/FILENAME,WST,1
/TITLE, Wedge Splitting Test with usermat.F
/NOPR     !Suppresses the expanded interpreted input data listing
/NOLIST   !Suppresses the data input listing

! Geometry, material properties, meshing parameters,
! and maximum CMOD may be changed by user for parametric studies.
! Input in N and mm

! Parameters for geometry (according to Instruction)
length=300
height=300
w=288
width=100
notch=135

! Material parameters
E=30000
mue=0.2
Gf=0.1
ft=3
c1=3
c2=6.93

! Parameters for mesh
edge_length=5  ! element edge length and notch width

! Maximum CMOD
max_CMOD=0.65

! End of user input section
! Do not change text below!

! Pre-processing
/prep7     !Enters the model creation preprocessor
ele1=185
mat1=1
mat2=2
ET,1,ele1   !Defines a local element type from the element library
KEYOPT,1,2,0

! Geometry in-plane
to=height-w
c=50
d=40
RECTNG,(length-edge_length)/2,(length+edge_length)/2,0,height-notch,                          !Creates a rectangular area anywhere on the working plane
RECTNG,0,(length-edge_length)/2,0,height-notch,   
RECTNG,(length+edge_length)/2,length,0,height-notch,
RECTNG,0,(length-edge_length)/2,height-notch,height-d,   
RECTNG,(length+edge_length)/2,length,height-notch,height-d,
RECTNG,0,(length-c)/2,height-d,height-to,   
RECTNG,(length+c)/2,length,height-d,height-to,
RECTNG,0,(length-c)/2,height-to,height,   
RECTNG,(length+c)/2,length,height-to,height,
! Extrude
VOFFST,1,width, ,    !Generates a volume, offset from a given area
VOFFST,2,width, ,   
VOFFST,3,width, ,
VOFFST,4,width, ,
VOFFST,5,width, ,
VOFFST,6,width, ,
VOFFST,7,width, ,
VOFFST,8,width, ,   
VOFFST,9,width, ,

! Meshing
VGLUE, ALL  ! glue all volumes   !Generates new volumes by "gluing" volumes.
ESIZE,edge_length  ! size control   !Specifies the default number of line divisions
VSEL,s,loc,y,0,height-notch
MAT,mat1
VMESH, ALL
VSEL,s,loc,y,height-notch,height-c
ASEL,s,loc,y,height-d
ASEL,r,loc,x,0,(length-edge_length)/2
ACCAT, ALL    !Concatenates multiple areas in preparation for mapped meshing
ASEL,s,loc,y,height-d   !Selects a subset of areas
ASEL,r,loc,x,(length+edge_length)/2,length
ACCAT, ALL
ASEL, ALL   !Selects a subset of areas
MAT,mat1
VMESH, ALL
VSEL,s,loc,y,height-c,height
MAT,mat2
VMESH, ALL
VSEL, ALL

! Boundary conditions
! Vertical load and self-weight are neglected.
LSEL,s,loc,y,height-to   !Selects a subset of lines
LSEL,r,loc,x,(length-c)/2
DL,all,,ux,0    !Defines DOF constraints on lines.
DL,all,,uy,0
DL,all,,uz,0
LSEL,all
LSEL,s,loc,y,height-to
LSEL,r,loc,x,(length+c)/2
DL,all,,uy,0
DL,all,,uz,0
LSEL,all

! Define user material mat1 by tb,user
TB,user,mat1,1,6    ! one temperature, six material properties
TBDATA, 1, E, mue, Gf, ft, c1, c2   ! material properties for temperature #1
TB,state,mat1,,8    ! eight state variables

! Define material mat2  (linear-elastic)
MP,ex ,mat2, E
MP,nuxy,mat2,mue

! Request output for state variables
OUTRES,svar,all
FINI

! Solution
/solu
NLGEOM,off  ! no geoemtrical nonlinearities
EQSLV, PCG,,1  !
NEQIT, 100
Outres,ALL,ALL
! six load steps following
NSUBST,1,10,1
LSEL,s,loc,y,height-to
LSEL,r,loc,x,(length+c)/2
DL,all,,ux, 1e-20
LSEL,all
TIME,1
SOLV
NSUBST,10,40,5
LSEL,s,loc,y,height-to
LSEL,r,loc,x,(length+c)/2
DL,all,,ux, max_CMOD*0.07
LSEL,all
TIME,2
SOLV
LSEL,s,loc,y,height-to
LSEL,r,loc,x,(length+c)/2
DL,all,,ux, max_CMOD*0.17
LSEL,all
TIME,3
SOLV
LSEL,s,loc,y,height-to
LSEL,r,loc,x,(length+c)/2
DL,all,,ux, max_CMOD*0.43
LSEL,all
TIME,4
SOLV
LSEL,s,loc,y,height-to
LSEL,r,loc,x,(length+c)/2
DL,all,,ux, max_CMOD*0.6
LSEL,all
TIME,5
SOLV
LSEL,s,loc,y,height-to
LSEL,r,loc,x,(length+c)/2
DL,all,,ux, max_CMOD
LSEL,all
TIME,6
SOLV
FINI

! Time-history postprocessor
/post26
NSEL,s,loc,y,height-to
NSEL,r,loc,x,(length+c)/2
*GET, node_count, NODE, 0, count  ! number of nodes along the loaded edge
NSEL,all
NUMVAR, 200
node_number_corner=NODE((length+c)/2,height-to,0)
NSOL,2,node_number_corner,u,x,CMOD ! store CMOD
*DO, counter,1,node_count
node_number=NODE((length+c)/2,height-to,(counter-1)*width/(node_count-1))
RFORCE,4+counter,node_number,f,x,CHRVAL(counter)  ! reactions
ADD,3,3,4+counter,,Split_force  ! calculate and store splitting force
*ENDDO
SOLU,4,NCMIT,,Iterations  ! store cumulative number of iterations
PRVAR,2,3,4 ! print time-history results in output window
XVAR,2
/TITLE, Splitting force versus CMOD
PLVAR,3  ! show Splitting force versus CMOD
/WAIT, 2
FINI

! General postprocessor
/post1
/TITLE, Maximum crack width
PLESOL,svar,3  ! contour plot maximum crack width
/WAIT, 2
/TITLE, Principal cracking strain
PLVECT,EPPL,,,,VECT,ELEM,ON,1 ! vector plot of principal cracking strain
/WAIT, 2
PATH,p1,2,20,30 ! define path
PPATH,1,,length/2,height-notch,width/2
PPATH,2,,length/2,0,width/2
PDEF,sigma_x,s,x, NOAV
PDEF,max_w,svar,3, NOAV
/TITLE, x-component of stress
PLPAGM,sigma_x,500,NODE  ! show x-component of stress
/WAIT, 2
/TITLE, Maximum crack width
PLPAGM,max_w,500,NODE  ! show maximum crack width
FINI