[交流] 利用cole-cole模型对实验测的的介电谱进行拟合已有1人参与

!!!using["luopt","math","win"]; //使用命名空间

g(a,b,c,d,f)= (a+(b-a)/(1+(2*pi*f*c)^2))-1.0i*(d/(2*pi*f*(1/(36*pi)*1e-9))+((b-a)*2*pi*f*c)/(1+(2*pi*f*c)^2));

目标函数(a,b,c,d : i,s, e11,e22 : max, f, e1, e2)=
{
    i=-1, s=0, while{++i<max, toreal[g(a,b,c,d,f(i,0)), &e11,&e22], s=s+[e1(i,0)-e11]^2+[e2(i,0)-e22]^2 },
    s
};

main(: tarray : max, f, e1, e2)=
{
    tarray=matrix{ //存放实验数据 //f    e1[realpart]    e2[imagpart]
        "20000000        78.6416        0.0101
20718771.93        78.5189        0.0451
21437543.86        78.5453        0.0435
// 省略数据
4405907421        74.7874        16.018
4500000000        74.6375        16.3285"
    },
    len[tarray,0,&max], f=tarray(all:0), e1=tarray(all:1),e2=tarray(all:2), //用len函数取矩阵的行数，f等取矩阵的列
    opt1[@目标函数] //opt1函数全局优化
};

!!!using["luopt","math","win"]; //使用命名空间

g(a,b,c,d,f)= (a+(b-a)/(1+(2*pi*f*c)^2))-1.0i*(d/(2*pi*f*(1/(36*pi)*1e-9))+((b-a)*2*pi*f*c)/(1+(2*pi*f*c)^2));

ge(a,b,c,d : i,s,e1,e2 : max, f, e12)=
{
    i=-1, while{++i<max, toreal[g(a,b,c,d,f(i,0)), &e1, &e2],  e12[i,0]=f(i,0), e12[i,1]=e1, e12[i,2]=e2}
};

init(main : tarray : max, f, e12)=
{
    tarray=matrix{ //存放实验数据 //f    e1[realpart]    e2[imagpart]
        "20000000        78.6416        0.0101
20718771.93        78.5189        0.0451
21437543.86        78.5453        0.0435
//省略数据
4500000000        74.6375        16.3285"
    },
    len[tarray,0,&max], f=tarray(all:0), //用len函数取矩阵的行数，f等取矩阵的列
    e12=new[real_s,max,3],
    ge[ 5.918198522529668     ,    78.489752592936   ,       -8.397205875077787e-012 ,  -6.746825318924285e-005],
    lusharex2[tarray, e12] //绘制共享x轴视图
};
chartwnd[@init]; //显示窗口并初始化