24小时热门版块排行榜

返回列表

【悬赏金币】回答本帖问题，作者科研古惑仔将赠送您 5 个金币

科研古惑仔

新虫 (初入文坛)

应助: 0 (幼儿园)
金币: 10
帖子: 4
在线: 6小时
虫号: 23271216
注册: 2020-07-27
专业: 制造系统与自动化

[求助] 仿真冷却时间添加已有1人参与

请教大神！！！我是做选区激光融化热物理仿真的，仿真过程不知道怎么在一层结束后添加冷却，希望大佬们解答一下，不胜感激！！！！下面是我的代码

finish
/clear

/units,si             !m-K-kg-s-J-W-Pa

/nerr,100000
/UIS,MSGPOP,3
/prep7
et,1,solid70
!******************************定义热分析物理参数************************************
MPTEMP,,,,,,,,
MPTEMP,1,298.15
MPTEMP,2,673.15
MPTEMP,3,1073.15
MPTEMP,4,1473.15
MPTEMP,5,1658.15
MPTEMP,6,1723.15
MPTEMP,7,1873.15
MPTEMP,8,2973.15
MPDATA,DENS,1,,7950
MPDATA,DENS,1,,7785
MPDATA,DENS,1,,7575
MPDATA,DENS,1,,7361
MPDATA,DENS,1,,7275
MPDATA,DENS,1,,7236
MPDATA,DENS,1,,6765
MPDATA,DENS,1,,6740
MPTEMP,,,,,,,,
MPTEMP,1,298.15
MPTEMP,2,673.15
MPTEMP,3,1073.15
MPTEMP,4,1473.15
MPTEMP,5,1658.15
MPTEMP,6,1723.15
MPTEMP,7,1873.15
MPTEMP,8,2973.15
MPDATA,C,1,,470
MPDATA,C,1,,560
MPDATA,C,1,,630
MPDATA,C,1,,700
MPDATA,C,1,,730
MPDATA,C,1,,830
MPDATA,C,1,,830
MPDATA,C,1,,960

MPTEMP,,,,,,,,
MPTEMP,1,298.15
MPTEMP,2,673.15
MPTEMP,3,1073.15
MPTEMP,4,1473.15
MPTEMP,5,1658.15
MPTEMP,6,1723.15
MPTEMP,7,1873.15
MPTEMP,8,2973.15
MPDATA,KXX,1,,13.4
MPDATA,KXX,1,,21.8
MPDATA,KXX,1,,27.2
MPDATA,KXX,1,,30.9
MPDATA,KXX,1,,32.4
MPDATA,KXX,1,,28.5
MPDATA,KXX,1,,30.5
MPDATA,KXX,1,,32.2

MPTEMP,,,,,,,,
MPTEMP,1,298.15
MPTEMP,2,673.15
MPTEMP,3,1073.15
MPTEMP,4,1473.15
MPTEMP,5,1658.15
MPTEMP,6,1723.15
MPTEMP,7,1873.15
MPTEMP,8,2973.15
MPDE,ENTH,1
MPDATA,ENTH,1,,298.15*470*7950
MPDATA,ENTH,1,,673.15*560*7785
MPDATA,ENTH,1,,1073.15*630*7575
MPDATA,ENTH,1,,1473.15*7361*700
MPDATA,ENTH,1,,1658.15*730*7275
MPDATA,ENTH,1,,1723.15*830*7236
MPDATA,ENTH,1,,1873.15*830*6765
MPDATA,ENTH,1,,2973.15*960*6740

*dim,conve,table,12,1,1,temp
conve(0,1,1)=1

conve(1,0,1)=298.15
conve(2,0,1)=473.15
conve(3,0,1)=673.15
conve(4,0,1)=873.15
conve(5,0,1)=1073.15
conve(6,0,1)=1273.15
conve(7,0,1)=1773.15
conve(8,0,1)=2073.15
conve(9,0,1)=2273.15
conve(10,0,1)=2473.15
conve(11,0,1)=2673.15
conve(12,0,1)=2873.15

conve(1,1,1)=12.12
conve(2,1,1)=24.23
conve(3,1,1)=40.38
conve(4,1,1)=72.69
conve(5,1,1)=125.00
conve(6,1,1)=150.38
conve(7,1,1)=200.00
conve(8,1,1)=250.65
conve(9,1,1)=300.65
conve(10,1,1)=350.6
conve(11,1,1)=400.6
conve(12,1,1)=450.6

!******************建立模型**********************
BLOCK,-0.0056,0.005,-0.0006,0.0012,0,-0.0003,
BLOCK,-0.0043,0.005,-0.0006,0.0012,-0.0002,-0.0003,
BLOCK,0,0.0006,0,0.0006,-0.0002,0.00003,
VSBV,1,2

vovlap,all       !体粘结
numcmp,all,,,low !压缩单元编号，重新编号

!******************划分网格**********************
allsel
vsel,u,volu,,1,2    !u指不选，volu是根据实体编号选择

wprota,,,90    !旋转工作平面，指XOZ平面由Z至X为方向旋转90度
wprota,,45
vsbw,all
wpcsys,-1 !根据坐标系，定义工作平面
wpoff,0.0006  !平移工作平面
wprota,,,90
wprota,,-45
vsbw,all

wpcsys,-1
wprota,,,90
wpoff,,,-0.0006
vsbw,all
wpoff,,,0.0012+0.0006
vsbw,all
wpcsys,-1
wpoff,,,-0.0002
vsbw,all
wpcsys,-1
wpoff,-0.0043
wprota,,,90
vsbw,all

lsel,s,lengh,,0.0006  !选择长度为0.006mm的直线
lesize,all,0.00002

lsel,s,lengh,,0.0018
lesize,all,,,0.0006/0.00002

lsel,s,lengh,,0.0002
lesize,all,,,4
lsel,s,lengh,,0.0001
lesize,all,,,2

vsel,s,volu,,2 !
aslv,s,1    !已选择体中选择面
lsla,s,1
lesize,all,0.00003
Mshkey,1
Mshape,0
Vmesh,all

allsel
lesize,all,0.0003
esize,0.0003
Mshkey,1
Mshape,0
Vmesh,all

v=1
p=225
radius=0.06e-3
ef=0.3
pi=3.1415926
qmax=2*ef*p/(pi*radius*radius) !***激光光斑中最大的热流密度

/solu !表示在求解器中进行设置
antype,4 !定义分析类型，4表示分析为瞬态分析。（可在后续操作中打开或关闭）
trnopt,full !完全瞬态积分法（默认参数，可以不写）
pred,on !打开预测校正（默认参数，可以不写）
solcontrol,on  !自动控制（默认参数，可以不写）
nropt,full,,on  !设置牛顿-拉普森方法（默认参数，可以不写）
cutcontrol,plslimit,10, !设置在一个线性求解中时间步的减少（作用不明确，建议写上）
lnsrch,on !线性搜索（对收敛有一定影响）
autots,on !自动步长（对收敛有一定影响）
tintp,,,,1,, !向后积分
tref,298.15  !参考温度
kbc,0 !连续性载荷
neqit,50 !规定每个子步中最大迭代次数,默认为25
outres,all !将输出结果全部显示出来

!***********************初始化载荷步参数**********************************

tinc=0.06e-3/v

!*******************************************稳态初值分析*********************************************
timint,off    !瞬态效应关闭
alls          !选取所有几何
ic,all,temp,298.15 ! 所有节点初始温度设定25
nsel,s,ext       !选择所有外部节点
sf,all,conv,%conve%,298.15       !在节点上施加面载荷，外部所有节点初始298K的对流系数

time,1e-6                      !设置时间间隔，为载荷步设置时间
deltim,1e-6,1e-7,1e-6          !设置时间步长
kbc,1          !载荷阶跃方式加载
allsel,all       !选中所有项目
solve

xmin0=0
xmax0=0.06e-3

xmin=xmin0
xmax=xmax0
xd=0.06e-3

ymin0=0
ymax0=0.06e-3

ymin=ymin0
ymax=ymax0
yd=0.06e-3 !

zmin=0
zmax=0.03e-3
zd=0.03e-3
zz=0.03e-3 !施加热源的表面

!*******************************************瞬态分析******************************************
/solu
timint,on

tm=tinc

lnum=0.0006/0.06e-3 !!!!

*do,n,1,10,1

*do,im,1,lnum,1 ! 从左往右扫描一道  →→→→→→→

esel,s,cent,y,ymin,ymax
esel,r,cent,x,xmin,xmax
esel,r,cent,z,zmin,zmax
eplot

*get,nemax,elem,,num,max                   !得到所有1类单元号码的最大值
*get,nemin,elem,,num,min

a=(xmin+xmax)/2    !v*tinc*im 热源位置(a,b,c)
b=v*tinc*im
c=zz

!***********************************以下施加热流密度载荷**************************
*do,i,nemin,nemax,1
  *if,esel(i),eq,1,then    !如果该单元在上面的集合里，则
xsy=centrx(i)             !读取该单元的中心坐标
ysy=centry(i)
zsy=centrz(i)
rr=abs(sqrt((xsy-a)*(xsy-a)+(ysy-b)*(ysy-b)+(zsy-c)*(zsy-c))) !该单元中心距离热源中心
*if,rr,le,radius,And,zsy,ge,0,then                !该单元中心在加热半径范围内
qr=qmax*exp(-2*rr*rr/(radius*radius))          !该单元中心处的热流大小
sfe,i,5,hflux,,qr          !在每个单元所指定的面上施加热源载荷
*endif
  *endif
*enddo
!***********************************************************************************

time,tm                   !时间间隔
!deltim,0.01,0.01,0.2       !时间步长
!deltim,tinc/20,tinc/30,tinc/10
deltim,4.5e-6,3e-6,9e-5
!deltim,2e-4,2e-4,2e-4

alls
solve

*do,i,nemin,nemax,1
*if,esel(i),eq,1,then    !如果该单元在上面的集合里，则
   xsy=centrx(i)                !读取该单元的中心坐标
   ysy=centry(i)
   zsy=centrz(i)
   rr=abs(sqrt((xsy-a)*(xsy-a)+(ysy-b)*(ysy-b))) !该单元中心距离热源中心
   *if,rr,le,radius,And,zsy,ge,0,then          !该单元中心在加热半径范围内
   sfedele,all,all,hflux                !删除每个单元六个面上的热载荷
      *endif
   *endif
*enddo

ymin=ymin+yd
ymax=ymax+yd

tm=tm+tinc
*enddo

xmin=xmin+yd
xmax=xmax+yd

ymin=ymin0
ymax=ymax0
*enddo

***********************************第二部分进行应力场分析******************************************

!******************************定义应力分析参数******************************
/prep7
MPTEMP,,,,,,,,
MPTEMP,1,298.15
MPTEMP,2,873.15
MPTEMP,3,1273.15
MPTEMP,4,1773.15
MPTEMP,5,2273.15
MPTEMP,6,2673.15
MPTEMP,7,3473.15
MPDATA,EX,1,,2E+11
MPDATA,EX,1,,1.35E+11
MPDATA,EX,1,,2E+10
MPDATA,EX,1,,2E+8
MPDATA,EX,1,,2E+7
MPDATA,EX,1,,2E+7
MPDATA,EX,1,,2E+7
MPDATA,PRXY,1,,0.33
MPDATA,PRXY,1,,0.35
MPDATA,PRXY,1,,0.36
MPDATA,PRXY,1,,0.40
MPDATA,PRXY,1,,0.40
MPDATA,PRXY,1,,0.41
MPDATA,PRXY,1,,0.45
MPTEMP,,,,,,,,
MPTEMP,1,298.15
MPTEMP,2,873.15
MPTEMP,3,1273.15
MPTEMP,4,1773.15
MPTEMP,5,2273.15
MPTEMP,6,2673.15
MPTEMP,7,3473.15
UIMP,1,REFT,,,
MPDATA,ALPX,1,,12E-6
MPDATA,ALPX,1,,13E-6
MPDATA,ALPX,1,,13.4E-6
MPDATA,ALPX,1,,14E-6
MPDATA,ALPX,1,,15E-6
MPDATA,ALPX,1,,15E-6
MPDATA,ALPX,1,,15E-6
TB,BKIN,1,6,2,1
TBTEMP,298.15
TBDATA,,3.45E+08,5.89E+09,,,,
TBTEMP,873.15
TBDATA,,2.12E+08,1.70E+09,,,,
TBTEMP,1073.15
TBDATA,,1.99E+08,1.40E+09,,,,
TBTEMP,1473.15
TBDATA,,1.00E+08,1.00E+08,,,,
TBTEMP,1623.15
TBDATA,,5.00E+07,1.00E+07,,,,
TBTEMP,1773.15
TBDATA,,5.00E+06,1.00E+06,,,,

/com,structural
/prep7
/config,nres,300000
alls
lsclear,all
etchg,tts

nsel,s,loc,z,-0.0003
d,all,ux,0,,,,uy,uz !在结构分析中，把节点载xyz三个方向上的位移全部约束掉

!***********************设置非线性求解选项（与温度场大同小异）*************
FINISH
/solu
antype,4
trnopt,full       !完全瞬态积分法
lumpm,0          !使用与单元相关的质量矩阵公式
nlgeom,on
pred,on
sstif,1
solcontrol,on
nropt,full,,on       !完全顿-拉普森方法
!cnvtol,u,,0.5, l2, -1       !设置收敛值，位移
!cnvtol,f,,0.05, l2, -1          !设置收敛值，力
cnvtol,u,,0.3
cnvtol,f,,0.03 !设置收敛值,力
cutcontrol,plslimit,10,
eqslv,sparse,,2
lnsrch,on
pstres,1
autots,on
tintp,,,,1,,
timint,on
tref,298.15
kbc,0          !连续性载荷
neqit,50
OUTRES,NSOL,LAST
OUTPR,NSOL,LAST

!***********************初始化载荷步参数**********************************
tinc=0.06e-3/v

!***********************稳态分析******************************************
alls
ldread,temp,1,,,,,rth       !读第一步的温度
/pbf,temp,,1
/replot
time,1e-6
deltim,1e-6,1e-7,1e-6
solve

!***********************应力计算******************************************

timint,on       ! 打开瞬态分析

!*************************生死单元**********************

esel,s,cent,z,0,0.00003
ekill,all

/solu

j=1
time=tinc

xmin0=0
xmax0=0.06e-3

xmin=xmin0
xmax=xmax0
xd=0.06e-3

ymin0=0
ymax0=0.06e-3

ymin=ymin0
ymax=ymax0
yd=0.06e-3 !

zmin=0
zmax=0.03e-3
zd=0.03e-3
zz=0.03e-3 !施加热源的表面

*do,n,1,10,1

*do,im,1,lnum,1 ! 从左往右扫描一道  →→→→→→→

esel,s,cent,y,ymin,ymax
esel,r,cent,x,xmin,xmax
esel,r,cent,z,zmin,zmax
ealive,all
eplot

ldread,temp,j+1,,,,,rth!
/pbf,temp,,1
/replot
autots,on
time,tm
deltim,0.25*tinc,0.1*tinc,0.25*tinc
alls
solve

ymin=ymin+xd
ymax=ymax+xd

tm=tm+tinc
j=j+1

*enddo

xmin=xmin+yd
xmax=xmax+yd

ymin=ymin0
ymax=ymax0
*enddo

回复此楼

» 猜你喜欢

1楼 2020-11-16 08:52:41

已阅回复此楼关注TA 给TA发消息送TA红花 TA的回帖

htbbzzg

铁杆木虫 (著名写手)

应助: 668 (博士)
金币: 9199
红花: 146
帖子: 2205
在线: 346小时
虫号: 728202
注册: 2009-03-22
性别: GG
专业: 动力学与控制

【答案】应助回帖

感谢参与，应助指数 +1

你是什么时候需要进行冷却？是在 n 循环中，还是在 im 循环中？
假设你是在 im 循环中要进行冷却，那么你可以在每个 im 的加热过程结束后，添加一个冷却过程。此时应该删除所有的加热载荷，然后添加冷却载荷 (必须有冷却载荷，否则温度不变。通常是对流载荷，如果前面已经定义过，也可以不重复定义)，如定义求解选项 (如终止时间，等)，进行求解。

赞一下(1人)

回复此楼

2楼2020-11-19 08:40:56

已阅回复此楼关注TA 给TA发消息送TA红花 TA的回帖

相关版块跳转我要订阅楼主科研古惑仔的主题更新