应《网络安全法》要求，自2017年10月1日起，未进行实名认证将不得使用互联网跟帖服务。为保障您的帐号能够正常使用，请尽快对帐号进行手机号验证，感谢您的理解与支持！

24小时热门版块排行榜    

小木虫论坛-学术科研互动平台 » 计算模拟区 » 仿真模拟 » ANSYS & ABAQUS » 急求！请教各位大神ANSYS网格划分问题！！！
51/1返回列表
查看: 2056  |  回复: 16
只看楼主 @他人 存档 新回复提醒 (忽略) 收藏    在APP中查看
当前只显示满足指定条件的回帖，点击这里查看本话题的所有回帖

虫友互助

新虫 (初入文坛)

[求助] 急求！请教各位大神ANSYS网格划分问题！！！ 已有3人参与

请问一个方管（空心）加上下底板，这是一个整体。
要对此进行网格划分，我首先将方管与钢板相交处divide切开，然后glue了一下，剩下的带有多条线的这个钢板（如图，一面为光面，一面带有两圈线）怎么进行网格划分啊？？？

急求！请教各位大神ANSYS网格划分问题！！！
4(6DPK22VB9R93L3F9L0XFR.png


急求！请教各位大神ANSYS网格划分问题！！！-1
{TC0OF9S@LP4BA]L%}T8W1G.png


急求！请教各位大神ANSYS网格划分问题！！！-2
7W[({]RZ9FQIK66JFGM4E]7.png
回复此楼

» 猜你喜欢
1楼 2017-02-06 09:16:35
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖

shgao20

专家顾问 (职业作家)

【答案】应助回帖

★ ★ ★ ★ ★ ★ ★ ★ ★ ★
虫友互助: 金币+10, ★★★★★最佳答案 2017-02-11 20:29:31
试了一下你的命令流，发现如果进一步切割会有很大困难，不如直接对方管部分划分四面体网格。由于方管部分的刚度远大于混凝土，厚度方向划分一层单元也是可以的。我采用单元尺寸 40 (与其它部分相同)，可以成功划分四面体网格，不过有很多警告：由 solid185 退化得到的四面体单元 (4 节点四面体) 计算精度很差，不推荐。后来改用 solid186 单元，同样可以划分四面体网格 (退化成 10 节点四面体单元)，且只有一个警告信息，是有少量单元质量超过警告线，但可以忽略。
  相应的命令流如下：
!1.定义单元与材料属性
FINISH
/CLEAR
/filn, how_meshing-186, 1

/PREP7
ET,1,SOLID65
ET,2,LINK180
ET,3,SOLID186

keyopt,1,1,1 !不考虑形函数的附加项
keyopt,1,3,2 !无筋单元的压碎后行为
keyopt,1,7,1 !考虑开裂后的应力释放

!混凝土材料性质
fck=20.1     !C30混凝土抗压强度标准值
ftk=2.01     !C30混凝土抗拉强度标准值
  
mp,ex,1,fck*0.19/0.0002
mp,prxy,1,0.2
tb,concr,1
tbdata,,0.5,0.95,ftk,-1
tb,miso,1,,11
tbpt,,0.0002,fck*0.19
tbpt,,0.0004,fck*0.36
tbpt,,0.0006,fck*0.51
tbpt,,0.0008,fck*0.64
tbpt,,0.0010,fck*0.75
tbpt,,0.0012,fck*0.84
tbpt,,0.0014,fck*0.91
tbpt,,0.0016,fck*0.96
tbpt,,0.0018,fck*0.99
tbpt,,0.002,fck
tbpt,,0.0033,fck

!纵筋材料性质
mp,ex,2,2e5
mp,prxy,2,0.3
mp,dens,2,7.85e-9
tb,bkin,2
tbdata,,400,0

!箍筋材料性质
mp,ex,3,2e5
mp,prxy,3,0.3
mp,dens,3,7.85e-9
tb,bkin,3
tbdata,,300,0

!型钢材料性质
mp,ex,4,2.06e5
mp,prxy,4,0.3
mp,dens,4,7.85e-9
tb,bkin,4
tbdata,,235,0

r,1
pi=acos(-1)
r,2,18*18*pi/4
r,3,8*8*pi/4

!2.创建几何模型
BLC5,0,0,360,360,20
wpoff,0,0,20
BLC5,0,0,100,200,1120   
BLC5,0,0,84,184,1120
wpoff,0,0,1120  
BLC5,0,0,360,360,20
VSBV,2,3
wpoff,0,0,20
BLC5,0,0,360,360,1040   
wpoff,0,0,200   
wpro,,,-90.000000   
wpoff,0,0,180   
BLC5,0,0,400,280,1000
wpro,,,-180.000000   
wpoff,0,0,360   
BLC5,0,0,400,280,1000   
VADD,ALL

!切分上部型钢柱
WPCSYS,-1
wpoff,0,0,20
VSBW,ALL
wpoff,0,0,80
VSBW,ALL
wpoff,0,0,200
VSBW,ALL
wpoff,0,0,840
VSBW,ALL
wpoff,0,0,20
VSBW,ALL
VSEL,S,LOC,Z,20,1140
wpro,,,-90.000000      
wpoff,0,0,42
VSBW,ALL
wpoff,0,0,-84
VSBW,ALL
wpro,,-90.000000,
wpoff,0,0,92
VSBW,ALL
wpoff,0,0,-184  
VSBW,ALL

!切分下部钢筋混凝土
ALLSEL,ALL
/REPLOT
WPCSYS,-1  
VSEL,S,LOC,Z,1160,2200

!切出纵筋位置
wpoff,0,0,1200
VSBW,ALL
wpoff,0,0,160
VSBW,ALL
wpoff,0,0,160
VSBW,ALL
wpro,,-90.000000,
VSBW,ALL
wpoff,0,0,100
VSBW,ALL
wpoff,0,0,40
VSBW,ALL
wpoff,0,0,-240
VSBW,ALL
wpoff,0,0,-40
VSBW,ALL
WPCSYS,-1  
wpro,,,-90.000000
VSBW,ALL
wpoff,0,0,140
VSBW,ALL
wpoff,0,0,-280
VSBW,ALL

!切出箍筋位置
wpoff,0,0,-1040
*DO,I,1,12
wpoff,0,0,80
VSBW,ALL
*ENDDO
wpoff,0,0,40
VSBW,ALL
wpoff,0,0,360
VSBW,ALL
wpoff,0,0,40
VSBW,ALL
*DO,I,1,11
wpoff,0,0,80
VSBW,ALL
*ENDDO
WPCSYS,-1  
wpoff,0,0,1280
VSBW,ALL
wpoff,0,0,160
VSBW,ALL
wpoff,0,0,120   
VSBW,ALL
wpoff,0,0,40   
VSBW,ALL
*DO,I,1,7
wpoff,0,0,80
VSBW,ALL
*ENDDO

!3.划分网格
!划分下部钢筋混凝土网格
!划分纵筋
WPCSYS,-1
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Y,100
LSEL,A,LOC,Y,-100
LSEL,R,LOC,Z,1200
LATT,2,2,2
LESIZE,ALL,40
LMESH,ALL

ALLSEL,ALL
LPLOT
LSEL,S,LOC,Y,100
LSEL,A,LOC,Y,-100
LSEL,R,LOC,Z,1360
LATT,2,2,2
LESIZE,ALL,40
LMESH,ALL

ALLSEL,ALL
LPLOT
LSEL,S,LOC,Y,100
LSEL,A,LOC,Y,-100
LSEL,R,LOC,Z,1520
LATT,2,2,2
LESIZE,ALL,40
LMESH,ALL

ALLSEL,ALL
LPLOT
LSEL,S,LOC,X,140
LSEL,A,LOC,X,0
LSEL,A,LOC,X,-140
LSEL,R,LOC,Y,140
LATT,2,2,2
LESIZE,ALL,40
LMESH,ALL

ALLSEL,ALL
LPLOT
LSEL,S,LOC,X,140
LSEL,A,LOC,X,-140
LSEL,R,LOC,Y,0
LATT,2,2,2
LESIZE,ALL,40
LMESH,ALL

ALLSEL,ALL
LPLOT
LSEL,S,LOC,X,140
LSEL,A,LOC,X,0
LSEL,A,LOC,X,-140
LSEL,R,LOC,Y,-140
LATT,2,2,2
LESIZE,ALL,40
LMESH,ALL

!划分箍筋
*DO,I,-1100,-220,80
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Z,1200
LSEL,A,LOC,Z,1520
LSEL,R,LOC,Y,-100,100
LSEL,R,LOC,X,I
LATT,3,3,2
LESIZE,ALL,40
LMESH,ALL
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Y,100
LSEL,A,LOC,Y,-100
LSEL,R,LOC,Z,1200,1520
LSEL,R,LOC,X,I
LATT,3,3,2
LESIZE,ALL,40
LMESH,ALL
*ENDDO

*DO,I,220,1100,80
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Z,1200
LSEL,A,LOC,Z,1520
LSEL,R,LOC,Y,-100,100
LSEL,R,LOC,X,I
LATT,3,3,2
LESIZE,ALL,40
LMESH,ALL
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Y,100
LSEL,A,LOC,Y,-100
LSEL,R,LOC,Z,1200,1520
LSEL,R,LOC,X,I
LATT,3,3,2
LESIZE,ALL,40
LMESH,ALL
*ENDDO

*DO,I,1200,2160,80
ALLSEL,ALL
LPLOT
LSEL,S,LOC,X,-140
LSEL,A,LOC,X,140
LSEL,R,LOC,Y,-140,140
LSEL,R,LOC,Z,I
LATT,3,3,2
LESIZE,ALL,40
LMESH,ALL
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Y,-140
LSEL,A,LOC,Y,140
LSEL,R,LOC,X,-140,140
LSEL,R,LOC,Z,I
LATT,3,3,2
LESIZE,ALL,40
LMESH,ALL
*ENDDO
!*
/VIEW,1,,-1
/ANG,1  
/REP,FAST   
VPLOT   

!划分混凝土
ALLSEL,ALL
MSHKEY,1
MSHAPE,0,3d
VPLOT

VSEL,S,LOC,Z,1160,2200
VATT,1,1,1
ESIZE,40
VMESH,ALL

!*
!划分上部型钢网格
!上部型钢都材料性质都为VATT,4,1,3
ALLSEL,ALL
/REPLOT
WPCSYS,-1  
VSEL,S,LOC,Z,0,1160
!*   设置型钢部分的单元属性
TYPE,   3   
MAT,       4
REAL,   
ESYS,       0   
SECNUM,
! 对上部型钢划分 FREE 网格
MSHKEY,0
MSHAPE,1,3d
FLST,5,26,6,ORDE,6  
FITEM,5,1   
FITEM,5,-6  
FITEM,5,8   
FITEM,5,-21
FITEM,5,28  
FITEM,5,-33
VSEL, , , ,P51X
CHKMSH,'VOLU'   
!*  
VMESH,all   
!*
allsel,all
eplot
save  
!*
赞一下(3人) 回复此楼

» 本帖已获得的红花（最新10朵）

虫友互助
9楼2017-02-10 07:44:44
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖
查看全部 17 个回答

shgao20

专家顾问 (职业作家)

【答案】应助回帖

感谢参与，应助指数 +1
进一步进行切割，使整个模型分为若干小的六面体 (这里可以全部切割为长方体)，然后使用 solid185 或 solid186 单元划分六面体网格。
  切割后，所有小的体积都是连在一起的，不用再进行 glue 操作。必要时做一下合并 KP 点即可。
赞一下 回复此楼
2楼2017-02-08 09:00:52
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖

小七工作室1

新虫 (著名写手)

【答案】应助回帖

感谢参与，应助指数 +1
这个用专业网格划分工具比较快的
赞一下 回复此楼
3楼2017-02-08 09:49:08
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖

虫友互助

新虫 (初入文坛)
引用回帖:
2楼: Originally posted by shgao20 at 2017-02-08 09:00:52
进一步进行切割，使整个模型分为若干小的六面体 (这里可以全部切割为长方体)，然后使用 solid185 或 solid186 单元划分六面体网格。
  切割后，所有小的体积都是连在一起的，不用再进行 glue 操作。必要时做一下合 ...

这其实是我模型的一部分，我的模型下部是钢筋混凝土，上部是型钢。建模时，我建模时我建为一个整体了。
下部钢筋混凝土的模型网格已划分好。由于是一个整体，所以上部型钢不能任意切分。
现在中间方管好划分，就是下部底板上有好多线，又不能任意切分，所以不知道该怎么办。
急求！请教各位大神ANSYS网格划分问题！！！-3
整个模型，已切分.png


急求！请教各位大神ANSYS网格划分问题！！！-4
下部钢筋混凝土划分的网格.png


急求！请教各位大神ANSYS网格划分问题！！！-5
型钢下底板的一面.png


急求！请教各位大神ANSYS网格划分问题！！！-6
型钢下底板的另一面.png
赞一下 回复此楼
4楼2017-02-08 16:29:30
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖
查看全部 17 个回答
普通表情 龙 兔 虎 猫
信息提示
关闭
请填处理意见
关闭