24小时热门版块排行榜

返回列表

grinmtyj

新虫 (小有名气)

应助: 1 (幼儿园)
金币: 66.8
散金: 5
红花: 1
帖子: 57
在线: 9.4小时
虫号: 4537223
注册: 2016-03-24
专业: 金属材料

[交流] 求助，ANSYS利用生死单元技术，温度传向为激活单元！已有6人参与

问题：加载热流密度计算后温度会传向未激活的单元

模型如图，划分网格也没问题。在基板上沉积4层熔覆层，每层高0.3mm，熔覆层长48mm，厚度5mm。

Finish
/filename,TA15 Ti2AlNb
/prep7
et,1,solid70
et,2,surf152
keyopt,2,4,1    !solid 70单元没有中间节点
keyopt,2,5,0    !表面效应单元加载对流，0和1均可?
keyopt,2,8,4    !根据流体温度计算对流系数
!根据Jmat Pro 模拟数据输入材料参数
!2号材料为薄壁
MPREAD,'TA15','dat','C:\Users\Administrator\Desktop\'
MPREAD,'Ti-22Al-25Nb','dat','C:\Users\Administrator\Desktop\'
block,0,0.15,0,0.006,0,0.1
wpave,0.05,0.006,0.05
block,0,0.048,0,0.0012,0,0.005
WPAVE,0,0,0
CSYS,0
vglue,all
wpave,0.05,0.006,0.05             !对基板做了切分，否则影响画网格
vsbw,all,,delete
wpave,0.05,0.006,0.055
vsbw,all,,delete
wprot,0,0,90
vsbw,all,,delete
wpave,0.098,0.006,0.055
vsbw,all,,delete
nummrg,all
numcmp,all

vsel,s,,,2                !赋予模型属性
vatt,2,,1,0
vsel,s,,,1
vsel,a,,,3,10,1
vatt,1,,1,0
allsel

vsel,s,mat,,2  !划分网格
esize,0.001
lesize,20,,,4
MSHAPE,0,3d
MSHKEY,1
vmesh,all
vsel,s,mat,,1
esize,0.003
MSHAPE,0,3d
MSHKEY,1
vmesh,all

/solu
antype,trans !瞬态分析
OUTRES,,ALL    !输出设置
toffst,273  !温度偏移量设置
nropt,auto
timint,1,therm !打开瞬态热分析
tunif,25    !初始温度
autos,on    !自动时间步长
kbc,0 !渐变载荷
pred,on    !打开时间预测器
lnsrch,on       !瞬态热分析设置
CNVTOL,HEAT, ,0.01,1,0.000001, !控制收敛准则
LUMPM,0    !不使用集中质量矩阵

asel,s,loc,x,0             !基板各表面加载对流
sfa,all,,conv,30,25
asel,s,loc,x,0.15
sfa,all,,conv,30,25
asel,s,loc,z,0
sfa,all,,conv,30,25
asel,s,loc,z,0.1
sfa,all,,conv,30,25
asel,s,loc,y,0
sfa,all,,conv,30,25
asel,s,loc,y,0.006
asel,u,,,9
sfa,all,,conv,30,25

esel,s,mat,,2          !选择2号材料，即沉积部分。将其杀死
ekill,all
esel,s,live

!每个载荷步移动一个网格即1mm，分析问题只加载10个载荷步。简化模型，假设为一个边长4mm的正方形光斑逐渐移动，热流密度载荷设为定值4,37e7。

local,12,0,0.05,0.0063,0.05 !建立局部坐标系方便筛选单元,局部坐标定点设在第一层的左上角。
dt=1/3 !每个载荷步时间0.3333秒
*do,i,1,10,1
nsel,s,loc,x,-0.002+(i-1)*0.001,0.002+(i-1)*0.001
nsel,r,loc,y,-0.0003,0
nsel,r,loc,z,0,0.005       !选择激活单元所包含的节点
esln,s,1
ealive,all
esel,s,live    !激活单元
eplot

esel,s,live                   !单元上表面加载HFLUX
nsel,s,loc,y,-0.0003,0          !选择光斑包含的节点
nsel,r,loc,x,-0.002+(i-1)*0.001,0.002+(i-1)*0.001
nsel,r,loc,z,0.0005,0.0045
esln,s,1
sfe,all,4,hflux,,4.37e7

allsel,all             !求解
time,dt*i
deltim,0.1,0.05,0.2 !求解子步设置
solve

sfedele,all,all,hflux !删除热流载荷

nsel,s,loc,z,0          !给已成形的单元两侧加载表面对流，顶面应该也还有暂不考虑
nsel,r,loc,y,-0.0003,0
nsel,r,loc,x,-0.002+(i-1)*0.001,0.002+(i-1)*0.001
sf,all,conv,30,25

nsel,s,loc,z,0.005
nsel,r,loc,y,-0.0003,0
nsel,r,loc,x,-0.002+(i-1)*0.001,0.002+(i-1)*0.001
sf,all,conv,30,25

*enddo

这是第一个载荷步加载热流的情况，可以看出激活单元的方式应该没问题。

这是加载3s之后的温度分布图，可以较明显的看出，温度分布不对，不是激活的单元才有温度，温度最大值甚至出现在了最顶面。

PS:有人提醒我可以用d命令添加温度约束，可还是发现温度会传向相邻的那个死单元，只有不会再往后传。

模型.jpg