应《网络安全法》要求，自2017年10月1日起，未进行实名认证将不得使用互联网跟帖服务。为保障您的帐号能够正常使用，请尽快对帐号进行手机号验证，感谢您的理解与支持！

24小时热门版块排行榜    

小木虫论坛-学术科研互动平台 » 计算模拟区 » 仿真模拟 » ANSYS & ABAQUS » ANSYS模仿装配式结构接触单元
51/1返回列表
查看: 1536  |  回复: 3
只看楼主 @他人 存档 新回复提醒 (忽略) 收藏    在APP中查看
当前只显示满足指定条件的回帖，点击这里查看本话题的所有回帖

小小憨

新虫 (初入文坛)

[求助] ANSYS模仿装配式结构接触单元 已有1人参与

装配式箱涵，用接触单元170和174分析不收敛

发自小木虫IOS客户端
回复此楼

» 猜你喜欢
1楼 2017-05-30 00:26:51
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖

小小憨

新虫 (初入文坛)
引用回帖:
2楼: Originally posted by shgao20 at 2017-05-30 07:29:03
需要你对自己的外推做一个详细的说明，最好把模型发上来。
只是这么简单的一句话，别人无法帮助你。

FINISH$/CLEAR$/PREP7
AS=490E-6$TF=200E3$EMST=1.95E11                           !预应力筋面积，张拉力,预应力筋弹模
HR=5.5$KR=6$HFT=3.5$TMRT=0.47E7                           !软土高度宽度、覆盖土层高度、软土弹模


ET,1,SOLID65$ET,2,LINK8$ET,3,SOLID45                      !定义箱涵、预应力筋、土
ET,4,170$ET,5,174$ET,6,173                                !接触目标元、面面元单元类型                  

MP,EX,1,3.0E10$MP,PRXY,1,0.2$MP,DENS,1,2500               !定义箱涵材料性质
MP,EX,2,1.95E11$MP,PRXY,2,0.3$MP,DENS,2,7921              !定义预应力筋性质     
MP,EX,3,1.25E7$MP,PRXY,3,0.4$MP,DENS,3,1950               !土的材料性质
MP,EX,4,TMRT$MP,PRXY,4,0.2$MP,DENS,4,1860                 !软土材料性质
TB,DP,3,$TBDATA,,5000,29.9,29.9                           !箱涵与土的摩擦系数、粘聚力、摩擦角、膨胀角
TB,DP,4,$TBDATA,,10000,4.3,4.3                            !箱涵与软土       
MP,MU,5,0.4                                               !节段间摩擦系数
MP,MU,6,0.2                                               !接触单元摩擦系数（桩-土）
MP,EX,7,2.6E8$MP,PRXY,7,0.2$MP,DENS,7,2500                !路面材料性质

R,1,2,0.08,0,90,2,0.04                                    !箱涵单元实常数
RMORE,0,0,2,0.06,90,0
R,2,491E-6,TF/(EMST*AS)$R,3$R,4                           !预应力筋、土、软土
R,5                                                       !173
R,6,,,1,0.3                                               !174单元实常数
R,7                                                       !路面

!!!!创建箱涵
*do,i,1,13
    k,1+12*(i-1),0,0,-2*(i-1)
    k,2+12*(i-1),6.8,0,-2*(i-1)
    k,3+12*(i-1),6.8,4.4,-2*(i-1)
    k,4+12*(i-1),0,4.4,-2*(i-1)
    k,5+12*(i-1),0.7,0.4,-2*(i-1)
    k,6+12*(i-1),6.1,0.4,-2*(i-1)
    k,7+12*(i-1),6.4,0.7,-2*(i-1)  
    k,8+12*(i-1),6.4,3.7,-2*(i-1)
    k,9+12*(i-1),6.1,4,-2*(i-1)
    k,10+12*(i-1),0.7,4,-2*(i-1)
    k,11+12*(i-1),0.4,3.7,-2*(i-1)
    k,12+12*(i-1),0.4,0.7,-2*(i-1)  
*enddo
*DO,I,1,13
   *IF,I,NE,14,THEN
      LSEL,NONE
      L,1+12*(I-1),2+12*(I-1)
      L,2+12*(I-1),3+12*(I-1)
      L,3+12*(I-1),4+12*(I-1)
      L,4+12*(I-1),1+12*(I-1)
      L,12+12*(I-1),5+12*(I-1)
      *DO,J,5,11
        L,J+12*(I-1),J+1+12*(I-1)
      *ENDDO
      AL,ALL
   *ELSE
      CYCLE
   *ENDIF
*ENDDO

*DO,I,2,13
   VOFFST,I,2
*ENDDO

K,301,0,0,1.62
K,302,6.8,0,2.81
K,303,6.8,4.4,2.81
K,304,0,4.4,1.62
KBETW,301,302,305,,7/68
KBETW,301,302,306,,61/68
KBETW,301,302,307,,64/68
KBETW,301,302,312,,4/68
KGEN,,305,306,,,0.4,,,,1
KGEN,,307,312,5,,0.7,,,,1
KGEN,2,307,,,,3
KGEN,2,306,,,,3.6
KGEN,2,305,,,,3.6
KGEN,2,312,,,,3

LSEL,NONE
L,301,302
L,302,303
L,303,304
L,304,301
L,312,305
*DO,I,5,11
   L,I+300,I+301
*ENDDO
AL,ALL

V,1,2,3,4,301,302,303,304          !13
V,5,6,7,12,305,306,307,312         !14
VSBV,13,14
V,12,7,8,11,312,307,308,311        !16
VSBV,15,13
V,11,8,9,10,311,308,309,310        !16
VSBV,14,13

VSYMM,X,15
VSYMM,Z,13,,,,,1
VGEN,2,13,,,,,-24,,,1
VGEN,2,13,,,6.8,,,,,1


!!!!预应力筋
*DO,I,1,3
  K,337+2*(I-1),0.49,0.49,0.8-6*(I-1)
  K,338+2*(I-1),0.49,0.49,-4.8-6*(I-1)
  L,337+2*(I-1),338+2*(I-1)
*ENDDO
K,343,0.49,0.49,-17.2
K,344,0.49,0.49,-24.8
L,343,344

LGEN,2,505,508,1,5.82
LGEN,2,505,508,1,,3.42
LGEN,2,505,508,1,5.82,3.42


ALLSEL,ALL
WPROTA,,,90$WPOFF,,,0.4$VSBW,ALL
WPOFF,,,0.3$VSBW,ALL
WPOFF,,,5.4$VSBW,ALL
WPOFF,,,0.3$VSBW,ALL
WPOFF,,0.4$WPROTA,,90$VSBW,ALL
WPOFF,,,-0.3$VSBW,ALL
WPOFF,,,-3$VSBW,ALL
WPOFF,,,-0.3$VSBW,ALL


WPCSYS,-1$LSBW,ALL
*DO,I,1,12
   WPOFF,,,-2
   LSBW,ALL
*ENDDO
WPCSYS,-1

LSEL,ALL$LSLA,S$LSEL,INVE$CM,SLINE,LINE                         !定义力筋线为元件

VSEL,ALL
VSEL,S,LOC,Z,-2,0$CM,CULVERT1,VOLU
VSEL,S,LOC,Z,-4,-2$CM,CULVERT2,VOLU
VSEL,S,LOC,Z,-6,-4$CM,CULVERT3,VOLU
VSEL,S,LOC,Z,-8,-6$CM,CULVERT4,VOLU
VSEL,S,LOC,Z,-10,-8$CM,CULVERT5,VOLU
VSEL,S,LOC,Z,-12,-10$CM,CULVERT6,VOLU
VSEL,S,LOC,Z,-14,-12$CM,CULVERT7,VOLU
VSEL,S,LOC,Z,-16,-14$CM,CULVERT8,VOLU
VSEL,S,LOC,Z,-18,-16$CM,CULVERT9,VOLU
VSEL,S,LOC,Z,-20,-18$CM,CULVERT10,VOLU
VSEL,S,LOC,Z,-22,-20$CM,CULVERT11,VOLU
VSEL,S,LOC,Z,-24,-22$CM,CULVERT12,VOLU
VSEL,S,LOC,Z,-27,-24$CM,CULVERT13,VOLU
VSEL,S,LOC,Z,0,3$CM,CULVERT14,VOLU

!!!!划分单元网格
CMSEL,S,SLINE                                 
LATT,2,2,2
LESIZE,ALL,0.8
LMESH,ALL                                        !划分预应力筋线

VSEL,ALL
LSEL,ALL
LSEL,S,LENGTH,,2
LESIZE,ALL,,,3
LSEL,S,LENGTH,,1.62
LSEL,A,LENGTH,,2.81
LESIZE,ALL,,,4
LSEL,S,LENGTH,,5.4,6
LESIZE,ALL,,,18
!LSEL,S,LENGTH,,3
!LESIZE,ALL,,,6
ESIZE,0.3$VATT,1,1,1$MSHKEY,1
VMESH,ALL                                        !划分箱涵
CMSEL,S,SLINE$NSLL,S,1
CEINTF,,UX,UY,UZ$ALLSEL,ALL

!!!!定义节段之间接触面
*AFUN,DEG
WPOFF,,,1.62$WPROTA,,,-ATAN(1.19/6.8)
CSWPLA,11,0
ASEL,S,LOC,Z,0
CM,AREA1,AREA
CSDELE,11
WPCSYS,-1

CMSEL,S,CULVERT14$ASLV,S$ASEL,R,LOC,Z,0$CM,AREA2,AREA
CMSEL,S,CULVERT1$ASLV,S$ASEL,R,LOC,Z,0$CM,AREA3,AREA
CMSEL,S,CULVERT1$ASLV,S$ASEL,R,LOC,Z,-2$CM,AREA4,AREA
CMSEL,S,CULVERT2$ASLV,S$ASEL,R,LOC,Z,-2$CM,AREA5,AREA
CMSEL,S,CULVERT2$ASLV,S$ASEL,R,LOC,Z,-4$CM,AREA6,AREA
CMSEL,S,CULVERT3$ASLV,S$ASEL,R,LOC,Z,-4$CM,AREA7,AREA
CMSEL,S,CULVERT3$ASLV,S$ASEL,R,LOC,Z,-6$CM,AREA8,AREA
CMSEL,S,CULVERT4$ASLV,S$ASEL,R,LOC,Z,-6$CM,AREA9,AREA
CMSEL,S,CULVERT4$ASLV,S$ASEL,R,LOC,Z,-8$CM,AREA10,AREA
CMSEL,S,CULVERT5$ASLV,S$ASEL,R,LOC,Z,-8$CM,AREA11,AREA
CMSEL,S,CULVERT5$ASLV,S$ASEL,R,LOC,Z,-10$CM,AREA12,AREA
CMSEL,S,CULVERT6$ASLV,S$ASEL,R,LOC,Z,-10$CM,AREA13,AREA
CMSEL,S,CULVERT6$ASLV,S$ASEL,R,LOC,Z,-12$CM,AREA14,AREA
CMSEL,S,CULVERT7$ASLV,S$ASEL,R,LOC,Z,-12$CM,AREA15,AREA
CMSEL,S,CULVERT7$ASLV,S$ASEL,R,LOC,Z,-14$CM,AREA16,AREA
CMSEL,S,CULVERT8$ASLV,S$ASEL,R,LOC,Z,-14$CM,AREA17,AREA
CMSEL,S,CULVERT8$ASLV,S$ASEL,R,LOC,Z,-16$CM,AREA18,AREA
CMSEL,S,CULVERT9$ASLV,S$ASEL,R,LOC,Z,-16$CM,AREA19,AREA
CMSEL,S,CULVERT9$ASLV,S$ASEL,R,LOC,Z,-18$CM,AREA20,AREA
CMSEL,S,CULVERT10$ASLV,S$ASEL,R,LOC,Z,-18$CM,AREA21,AREA
CMSEL,S,CULVERT10$ASLV,S$ASEL,R,LOC,Z,-20$CM,AREA22,AREA
CMSEL,S,CULVERT11$ASLV,S$ASEL,R,LOC,Z,-20$CM,AREA23,AREA
CMSEL,S,CULVERT11$ASLV,S$ASEL,R,LOC,Z,-22$CM,AREA24,AREA
CMSEL,S,CULVERT12$ASLV,S$ASEL,R,LOC,Z,-22$CM,AREA25,AREA
CMSEL,S,CULVERT12$ASLV,S$ASEL,R,LOC,Z,-24$CM,AREA26,AREA
CMSEL,S,CULVERT13$ASLV,S$ASEL,R,LOC,Z,-24$CM,AREA27,AREA

WPOFF,,,-26.81$WPROTA,,,-ATAN(1.19/6.8)
CSWPLA,12,0
ASEL,S,LOC,Z,0
CM,AREA28,AREA
CSDELE,12
WPCSYS,-1

CMSEL,S,AREA3$CMSEL,A,AREA5$CMSEL,A,AREA7$CMSEL,A,AREA9$CMSEL,A,AREA11$CMSEL,A,AREA13$CMSEL,A,AREA14
CMSEL,A,AREA16$CMSEL,A,AREA18$CMSEL,A,AREA20$CMSEL,A,AREA22$CMSEL,A,AREA24$CMSEL,A,AREA26
NSLA,S,1$REAL,6$TYPE,4$MAT,5$ESURF,ALL$ALLSEL,ALL                                              !定义目标元

CMSEL,S,AREA2$CMSEL,A,AREA4$CMSEL,A,AREA6$CMSEL,A,AREA8$CMSEL,A,AREA10$CMSEL,A,AREA12$CMSEL,A,AREA15
CMSEL,A,AREA17$CMSEL,A,AREA19$CMSEL,A,AREA21$CMSEL,A,AREA23$CMSEL,A,AREA25$CMSEL,A,AREA27
NSLA,S,1$REAL,6$TYPE,5$ESURF,ALL$ALLSEL,ALL


!!!!创建土体
KBETW,304,303,,,-16.6/6.8                         !981        
KBETW,304,303,,,23.4/6.8                          !982
KGEN,2,981,982,,,HFT                           !983,984
KGEN,2,981,982,,,HFT+0.4                        !985,986
KSEL,S,,,981,986                              
KGEN,2,ALL,,,,,-28.43                             !987-992
KGEN,2,981,982,,,-4.4                           !993,994
KGEN,2,993,994,,,,-28.43                        !995,996
KGEN,2,993,994,,,,-14.215+KR/2
KGEN,2,993,994,,,,-14.215-KR/2
KGEN,2,993,996,,,-HR                           
KGEN,2,993,994,,,-HR,-14.215+KR/2
KGEN,2,993,994,,,-HR,-14.215-KR/2

K,1301,0,0,1.62
K,1302,6.8,0,2.81
K,1303,6.8,4.4,2.81
K,1304,0,4.4,1.62
K,1325,6.8,0,-25.62
K,1326,0,0,-26.81
K,1327,0,4.4,-26.81
K,1328,6.8,4.4,-25.62


VSEL,NONE
V,983,984,986,985,989,990,992,991         !路面铺装层
CM,ROAD,VOLU
VATT,7,7,3

VSEL,NONE
V,981,982,984,983,987,988,990,989         !覆盖土
CM,FUGAITU,VOLU
VATT,3,3,3

VSEL,NONE                                         !回填土
KSEL,ALL
V,993,1301,1304,981,995,1326,1327,987
V,1302,994,982,1303,1325,996,988,1328
CM,BIANTU,VOLU
VATT,3,3,3

VSEL,NONE
V,1001,1002,994,993,1005,1006,998,997         !地基土
V,1007,1008,1000,999,1003,1004,996,995         !地基土
CM,DIJITU,VOLU
VATT,3,3,3

VSEL,NONE
V,1005,1006,998,997,1007,1008,1000,999         !软土
CM,RUANTU,VOLU                  
VATT,4,4,3


!!!!划分单元(/psymb,ldir,1显示线的方向）
ALLSEL,ALL
LSEL,S,LENGTH,,40.60,40.62
LESIZE,ALL,,,40,-0.2

LSEL,S,LENGTH,,4.4
LESIZE,ALL,,,15

!LSEL,S,LENGTH,,16.84,16.86
LSEL,S,,,1659,1662,3
LSEL,A,,,1666,1668,2
LESIZE,ALL,,,14,3

LSEL,S,,,1657,1670,13
LSEL,A,,,1673,1676,3
LESIZE,ALL,,,14,1/3

LSEL,S,LENGTH,,14.215-KR/2
LSEL,A,LENGTH,,28.43
LSEL,A,LENGTH,,KR
LESIZE,ALL,0.7
VSEL,ALL
MSHKEY,1
ESIZE,0.5
VMESH,ALL


!!!!创建箱涵与土体接触对接触对
ALLSEL,ALL
VSEL,S,LOC,X,0,6.8
VSEL,R,LOC,Y,0,4.4
ASLV,S$ASEL,R,LOC,X,0$CM,AREA31,AREA
ASLV,S$ASEL,R,LOC,X,6.8$CM,AREA32,AREA
ASLV,S$ASEL,R,LOC,Y,0$CM,AREA33,AREA
ASLV,S$ASEL,R,LOC,Y,4.4$CM,AREA34,AREA

CMSEL,S,AREA31$CMSEL,A,AREA32$CMSEL,A,AREA33$CMSEL,A,AREA34                  !目标元
NSLA,S,1
REAL,5
TYPE,4
MAT,6
ESURF,ALL                                             

ALLSEL,ALL
ASEL,S,,,66,170,104
ASEL,A,,,242,272,30
ASEL,A,,,353,370,17
NSLA,S,1
REAL,5
TYPE,6
ESURF,ALL                                                  !接触元

!!!!添加约束(土体上面自由面，底面竖向约束，侧面水平约束）
ASEL,ALL
ASEL,S,LOC,X,-16.6$ASEL,A,LOC,X,23.4$DA,ALL,UX
ASEL,S,LOC,Y,-5.5$DA,ALL,UY
WPOFF,,,1.62$WPROTA,,,-ATAN(1.19/6.8)
CSWPLA,13,0
ASEL,S,LOC,Z,0
CSDELE,13
DA,ALL,UZ
WPCSYS,-1
WPOFF,,,-26.81$WPROTA,,,-ATAN(1.19/6.8)
CSWPLA,14,0
ASEL,S,LOC,Z,0
CSDELE,14
DA,ALL,UZ
WPCSYS,-1


!!!!施加荷载(/PSYMB,ADIR,1)(/PSF,PRES,NORM,2,0,1)
ALLSEL,ALL
ASEL,S,LOC,Y,8.3
!ASEL,R,LOC,X,0,6.8
SFA,ALL,1,PRES,10.5E3                                         
ALLSEL,ALL

!!!!结构分析
/SOLU
ANTYPE,STATIC
NLGEOM,ON                                                   !大变形
AUTOTS,ON                                                   !自动时间步
NROPT,UNSYM
ACEL,,9.8
TIME,1
NSUBST,50                                                  !荷载步
OUTRES,ALL,ALL
SOLVE
FINISH

!!!!查看结果
/POST1
SET,LAST
ESEL,S,REAL,,1
NSLE,S
NSEL,R,LOC,Y,0
NSEL,R,LOC,X,3.4,3.52
PLNSOL,U,Z
PLNSOL,S,Z
这是我的命令流，分析装配式涵洞沉降，有接触单元也有预应力筋，1、分析时output window窗口出现Constraint equations may not be valid for elements that undergo large deflections2、分析时提示a check of your model data produced 1 warnings。
我个人认为预应力筋有问题，初次用ansys建模，请教大神

发自小木虫IOS客户端
赞一下 回复此楼
3楼2017-05-31 19:45:24
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖
查看全部 4 个回答

shgao20

专家顾问 (职业作家)

【答案】应助回帖

感谢参与，应助指数 +1
需要你对自己的外推做一个详细的说明，最好把模型发上来。
只是这么简单的一句话，别人无法帮助你。
赞一下 回复此楼
2楼2017-05-30 07:29:03
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖

shgao20

专家顾问 (职业作家)
引用回帖:
3楼: Originally posted by 小小憨 at 2017-05-31 19:45:24
FINISH$/CLEAR$/PREP7
AS=490E-6$TF=200E3$EMST=1.95E11                           !预应力筋面积，张拉力,预应力筋弹模
HR=5.5$KR=6$HFT=3.5$TMRT=0.47E7                           !软土高度宽度、覆盖土层高度 ...

错误信息说的很清楚了，约束方程对大挠度分析无效。关闭大挠度选项试试：
    NLGEOM,ON
  改为：
    NLGEOM,OFF
  或删除改命令。
赞一下 回复此楼
4楼2017-06-01 08:18:01
已阅   回复此楼   关注TA 给TA发消息 送TA红花 TA的回帖
查看全部 4 个回答
普通表情 龙 兔 虎 猫
信息提示
关闭
请填处理意见
关闭